FuncNet simple test

#!/usr/bin/perl

# Checks the status of the last registry test and reports appropriately.

use warnings;
use strict;

use XML::XPath;
use XML::XPath::XMLParser;
use LWP::UserAgent;
use Date::Manip;

# Get the output from the last status check

my $ua = LWP::UserAgent->new;
my $monitor_url = "http://gene3d.biochem.ucl.ac.uk:8090/FuncNetServiceMonitor/service-monitor.xml";
my $response = $ua->get( $monitor_url );
unless( $response->is_success )
{
    warn "Could not retrieve $monitor_url: ", $response->status_line, "\n";
    exit 2;
}

my $xpath = XML::XPath->new( xml => $response->content );

# Get the time at which the service was last tested

my $nodeset = $xpath->find( '/services/service[name="FrontEndService"]/timestamp/text()' );
my @nodes = $nodeset->get_nodelist;

if( @nodes > 1 )
{
    warn "Found more than one matching timestamp node\n";
    exit 3;
}

if( @nodes == 0 )
{
    warn "Found no matching timestamp node\n";
    exit 4;
}

# We will check to see if the last status test was more than 30mins ago,
# but we won't actually perform this until we've tested for actual errors

my $timestamp = ParseDateString( XML::XPath::XMLParser::as_string( $nodes[ 0 ] ) );
my $half_an_hour_ago = DateCalc( "now", "- 30minutes" );

# Get the actual status node

$nodeset = $xpath->find( '/services/service[name="FrontEndService"]/status/text()' );
@nodes = $nodeset->get_nodelist;

if( @nodes > 1 )
{
    warn "Found more than one matching status node\n";
    exit 5;
}

if( @nodes == 0 )
{
    warn "Found no matching status node\n";
    exit 6;
}

my $status = XML::XPath::XMLParser::as_string( $nodes[ 0 ] );
if( $status ne 'OK' )
{
    warn "The front-end service is showing a status of $status\n";
    if( $status eq 'ERROR' )
    {
        exit 1;
    }
    else
    {
        exit 7;
    }
}

# Now look at time of test -- warning if too old

if( Date_Cmp( $timestamp, $half_an_hour_ago ) < 0 )
{
    warn "The service shows OK but the status test was last performed at "
        . UnixDate( $timestamp, "%T on %A the %E of %B, %Y" ) . "\n";
    exit 8;
}